来把 org-roam 笔记发布出去吧

(setq org-hugo-base-dir "~/Documents/roam-publish/")

(defun my/org-roam-filter-by-tag (tag-name)
  (lambda (node)
    (member tag-name (org-roam-node-tags node))))

(defun my/org-roam-list-notes-by-tag (tag-name)
  (mapcar #'org-roam-node-file
          (seq-filter
           (my/org-roam-filter-by-tag tag-name)
           (org-roam-node-list))))

(defun my/org-roam-export-all ()
  "Re-exports all Org-roam files to Hugo markdown."
  (interactive)
  (dolist (org-file (my/org-roam-list-notes-by-tag "publish"))
    (with-current-buffer (find-file org-file)
        (my/org-roam-publish t))))

(defun my/insert--backlinks (&optional heading-func)
  (if-let ((backlinks (org-roam-backlinks-get (org-roam-node-at-point) :unique t)))
      (save-excursion
        (when heading-func
          (funcall heading-func))
        (insert " 反向链接\n")
        (dolist (backlink backlinks)
          (let* ((source-node (org-roam-backlink-source-node backlink))
                 (point (org-roam-backlink-point backlink)))
            (insert
             (format "- [[id:%s][%s]]\n"
                     (org-roam-node-id source-node)
                     (org-roam-node-title source-node))))))))

(defun my/insert-backlinks ()
  (goto-char (point-min))
  (org-shifttab 0)
  (while (= 0 (org-next-visible-heading 1))
    (when (assoc "ID" (org-entry-properties))
      (my/insert--backlinks
       (lambda ()
         (org-insert-subheading t)))))
  (goto-char (point-min))
  (my/insert--backlinks
   (lambda ()
     (goto-char (point-max))
     (insert "* "))))

(defun my/extract-org-roam-id (origin-filename)
  (save-excursion
    (goto-char (point-min))
    (let ((matche '()))
      (while (re-search-forward "\\[\\[id:\\(.*?\\)]\\[.*?\\]\\]" nil t)
        (when-let* ((uuid (match-string-no-properties 1))
                    (roam-node (org-roam-node-from-id uuid))
                    (file-name (car (org-roam-id-find uuid))))
          (when (member "publish" (org-roam-node-tags roam-node))
            (push file-name matche))))
      (delete origin-filename (seq-uniq matche)))))

(defun my/org-roam-publish (&optional skip-publish skip-update-backlinks)
  "Publish current file"
  (interactive)
  (goto-char (point-min))
  (org-roam-update-org-id-locations)
  (org-roam-tag-add (list "publish"))
  (unless skip-update-backlinks
    (org-roam-set-keyword "hugo_lastmod" (format-time-string "%Y-%m-%d %H:%M:%S")))
  (save-buffer)
  (let ((publish-content (buffer-string))
        (origin-filename (buffer-file-name))
        (filename (concat (file-name-base (buffer-file-name)) ".org")))
    (with-temp-buffer
      (erase-buffer)
      (insert publish-content)
      (org-mode)
      (org-roam-set-keyword "EXPORT_FILE_NAME" filename)
      (org-roam-tag-remove (list "publish"))
      (my/insert-backlinks)
      (unless skip-update-backlinks
        (let ((back-files (my/extract-org-roam-id origin-filename)))
          (dolist (back-file back-files)
            (message back-file)
            (with-current-buffer (get-file-buffer back-file)
              (my/org-roam-publish t t)))))
      (org-hugo-export-wim-to-md)))
  (unless skip-publish
    (async-shell-command (concat
                          "cd " org-hugo-base-dir
                          " && " "git add ."
                          (if (yes-or-no-p "Push now?")
                              (concat " && " "git commit -m '[post] new post'"
                                      " && " "git push"))) "*Messages*"))
  (message "publish new post!"))

window.Isso.init()
window.Isso.fetchComments()

<section id="isso-thread" data-title="{{ .Title }}" data-isso-id="{{ .RelPermalink }}">